For reference purposes, I’ve pulled out several here.

To work around this issue, simply stop and restart the dnscache service (DNS Client service). This service is the one that actually registers names with the DNS server. Restarting it will cause it to re-inventory the interfaces and stop uploading old data.

The following script will get rid of old, expired updates and their files for you. Just run it on a regular basis to clean up the system.

Save the following as CleanupOldUpdates.wsf:

<job>
<runtime>
<named name="AlsoRemoveUnrequired" type=string required=false helpstring="Removes updates that are not required that are more than n days old (default is 7)" />
</runtime>
<script language=vbscript>
'This script will scan through the updates and remove old items from
'deployments, packages, and update lists where the Expired attribute
'is set to TRUE.

Set SMS = GetObject("winmgmts://./root/sms/site_***") 'Replace *** with your sitecode
Set SO = WScript.StdOut
Set WMIDate = CreateObject("WbemScripting.SWbemDateTime")
Set aNamed = WScript.Arguments.Named
If aNamed.Exists("AlsoRemoveUnrequired") Then
	If aNamed("AlsoRemoveUnrequired") = "" Then
		UnrequiredLimit = 7
	Else
		If IsNumeric(aNamed("AlsoRemoveUnrequired")) Then
			UnrequiredLimit = CLng(aNamed("AlsoRemoveUnrequired"))
		Else
			WScript.Arguments.ShowUsage
			WScript.Quit
		End If
	End If
	SO.WriteLine "Will also consider updates more than " & UnrequiredLimit & " days old that are not required to be" & vbCrLf & "expired"
	UnrequiredDate = DateAdd("d",0-UnrequiredLimit,Now())
	WMIDate.SetVarDate UnrequiredDate
	WMIDate.UTC=False
	UnrequiredDateWMI = WMIDate.Value
	SO.WriteLine UnrequiredDate
	SO.WriteLine UnrequiredDateWMI
End If

'*************************************************************************
' Clean up Deployments
'*************************************************************************

SO.WriteLine "*******************************************************************************"
SO.WriteLine "Cleaning up Deployments"
SO.WriteLine "*******************************************************************************"
SO.WriteLine

'Get the assignments and parse through them, looking for expired updates
Set collAssignments = SMS.Get("SMS_UpdatesAssignment").Instances_
Dim AssignedCIs()

For Each AssignmentItem in collAssignments
	Set Assignment=SMS.Get(Split(AssignmentItem.Path_,":")(1))	'This object has lazy properties that need to be obtained
	SO.WriteLine "ASSIGNMENT: " & Assignment.AssignmentName & " [" & Assignment.AssignmentID & "]"

	'We'll hold the updates assigned to this list in an array
	UpdateCount = 0
	UpdateCountOriginal = 0
	Redim AssignedCIs(UpdateCount)

	'Since enumerating updates is "expensive", we'll only target assignments that are known
	'to have expired updates
	If Assignment.ContainsExpiredUpdates or aNamed.Exists("AlsoRemoveUnrequired") Then
		SO.WriteLine "  Getting expired updates..."
		For I = LBound(Assignment.AssignedCIs) to UBound(Assignment.AssignedCIs)
			If UBound(Assignment.AssignedCIs)<>0 Then SO.Write String(79,Chr(8)) & FormatPercent(I/UBound(Assignment.AssignedCIs))
			Set Update=SMS.Get("SMS_SoftwareUpdate.CI_ID=" & Assignment.AssignedCIs(I))
			If Update.IsExpired Then
				SO.WriteLine String(79,Chr(8)) & "  " & Update.ArticleID & " is expired [" & Update.CI_ID & "]"
			ElseIf aNamed.Exists("AlsoRemoveUnrequired") and Update.NumMissing=0 and Update.NumPresent=0 and Update.DateRevised<UnrequiredDateWMI Then
				SO.WriteLine String(79,Chr(8)) & "  " & Update.ArticleID & " is not required [" & Update.CI_ID & "]"
			Else
				Redim Preserve AssignedCIs(UpdateCount)
				AssignedCIs(UpdateCount) = Update.CI_ID
				UpdateCount = UpdateCount + 1
			End If
			UpdateCountOriginal = UpdateCountOriginal + 1
		Next
		SO.Write String(79,Chr(8))

		'If the array is a different size than the original array, we've removed some
		If UpdateCount < UpdateCountOriginal Then
			SO.WriteLine "    Removed " & UpdateCountOriginal-UpdateCount & " update(s)"

			'Save the changes
			If Join(AssignedCIs,",")="" Then
				SO.WriteLine "!!! All updates need to be removed from this deployment.  Please add new ones or remove the deployment altogether."
				SO.WriteLine
			Else
				Assignment.AssignedCIs = AssignedCIs
				Assignment.Put_
			End If
		End If
	End If
Next

'*************************************************************************
' Clean up Packages
'*************************************************************************

SO.WriteLine
SO.WriteLine
SO.WriteLine "*******************************************************************************"
SO.WriteLine "Cleaning up Packages"
SO.WriteLine "*******************************************************************************"
SO.WriteLine

'Get the deployment packages
Set collPackages = SMS.Get("SMS_SoftwareUpdatesPackage").Instances_

'Find a list of all expired updates that are provisioned
Set collUpdates = SMS.ExecQuery("Select * from SMS_SoftwareUpdate where IsContentProvisioned = 1 and IsExpired = 1")
If aNamed.Exists("AlsoRemoveUnrequired") Then _
	Set collUpdatesUnreq = SMS.ExecQuery("Select * from SMS_SoftwareUpdate where IsContentProvisioned = 1 and NumMissing = 0 and NumPresent = 0 and DateRevised < '" & UnrequiredDate & "'")
Dim ContentIDs()
ContentCount = 0

For Each oUpdate in collUpdates
	SO.WriteLine "Compiling content IDs for expired update " & oUpdate.ArticleID & " [" & oUpdate.CI_ID & "]"
	Set collContent = SMS.ExecQuery("Select * from SMS_CIToContent where CI_ID = " & oUpdate.CI_ID)
	For Each oContent in collContent
		If oContent.ContentDownloaded Then
			SO.WriteLine "    Added content ID " & oContent.ContentID
			Redim Preserve ContentIDs(ContentCount)
			COntentIDs(ContentCount) = oContent.ContentID
			ContentCount = ContentCount + 1
		End If
	Next
Next

If aNamed.Exists("AlsoRemoveUnrequired") Then
	For Each oUpdate in collUpdatesUnreq
		SO.WriteLine "Compiling content IDs for unrequired update " & oUpdate.ArticleID & " [" & oUpdate.CI_ID & "]"
		set collContent = SMS.ExecQuery("Select * from SMS_CItoContent where CI_ID = " & oUpdate.CI_ID)
		For Each oContent in collContent
			if oContent.ContentDownloaded Then
				SO.WriteLine "    Added content ID " & oContent.ContentID
				Redim Preserve ContentIDs(ContentCount)
				ContentIDs(ContentCount) = oContent.ContentID
				ContentCount = ContentCount + 1
			End If
		Next
	Next
End If

SO.WriteLine "Found a total of " & ContentCount & " content item(s) to be removed"

If ContentCount > 0 Then
	On Error Resume Next
	For Each oPackage in collPackages
		SO.WriteLine "Removing from " & oPackage.Name & " [" & oPackage.PackageID & "]"
		oPackage.RemoveContent ContentIDs, True
		If Err.Number = 0 Then SO.WriteLine "    Success"
	Next
	On Error Goto 0
End If

'*************************************************************************
' Clean up Update Lists
'*************************************************************************

SO.WriteLine
SO.WriteLine
SO.WriteLine "*******************************************************************************"
SO.WriteLine "Cleaning up Update Lists"
SO.WriteLine "*******************************************************************************"
SO.WriteLine

'Get the update lists and parse through them, looking for expired updates
Set collLists = SMS.Get("SMS_AuthorizationList").Instances_
Dim Updates()

For Each ListItem in collLists
	'SO.WriteLine Split(ListItem.Path_,":")(1)
	Set List=SMS.Get(Split(ListItem.Path_,":")(1))	'This object has lazy properties that need to be obtained
	SO.WriteLine "UPDATE_LIST: " & List.LocalizedDisplayName & " [" & List.CI_ID & "]"

	'We'll hold the updates assigned to this list in an array of CI_IDs
	UpdateCount = 0
	Redim arrUpdate(UpdateCount)

	'Enumerate the existing updates assigned to the list
	Set collUpdateIDs = SMS.ExecQuery("Select SMS_SoftwareUpdate.* from SMS_CIRelation join SMS_SoftwareUpdate on SMS_CIRelation.ToCIID=SMS_SoftwareUpdate.CI_ID where SMS_CIRelation.FromCIID=" & List.CI_ID)
	'SO.WriteLine collUpdateIDs.Count

	'Check each one and, if expired, don't add it into our array - only good updates go into the array
	If collUpdateIDs.Count>0 Then
		For Each Update in collUpdateIDs
			If Update.IsExpired Then
				SO.WriteLine String(79,Chr(8)) & "  " & Update.ArticleID & " is expired [" & Update.CI_ID & "]"
			ElseIf aNamed.Exists("AlsoRemoveUnrequired") and Update.NumMissing=0 and Update.NumPresent=0 and Update.DateRevised<UnrequiredDateWMI Then
				SO.WriteLine String(79,Chr(8)) & "  " & Update.ArticleID & " is not required [" & Update.CI_ID & "]"
			Else
				Redim Preserve arrUpdate(UpdateCount)
				arrUpdate(UpdateCount) = Update.CI_ID
				UpdateCount = UpdateCount + 1
			End If
		Next
	End If

	'If the array is a different size than the original collection, we've removed some
	If UpdateCount < collUpdateIDs.Count Then
		SO.WriteLine "    Removed " & (collUpdateIDs.Count - UpdateCount) & " update(s)"

		'Save the new update membership
		If Join(arrUpdate,",") <> "" Then
			List.Updates = arrUpdate
			List.Put_
		Else
			SO.WriteLine "!!! All updates need to be removed - please remove this list outright or add current updates before cleaning up old ones."
			SO.WriteLine
		End If
	End If
Next
</script>
</job>

The following script can be used to combine several monthly update lists for the specified year into one single list. This can then be deployed to clients using the script found in Part 2 of this series.

Save the following file as CombineYears.wsf:

<job>
<runtime>
<description>
This utility will combine several "Software Updates YYYY-MM" lists into a
single list for a given year.  This allows the individual lists to be
unassigned and to utilize the annual list for future assignments.  This
helps to simplify and minimize the amount of assignments that the user
workstation must churn through when analyzing for updates
</description>
<unnamed name=Year required=1 many=true helpstring="The four digit year of lists to be combined" />
</runtime>
<script language=VBScript>

'Connect to SCCM
Set SCCM = GetObject("winmgmts://./root/sms/site_***") 'Replace *** with your sitecode

Set WMIDate = CreateObject("WBemSCripting.SWbemDateTime")
Set SO = WScript.StdOut

'Validate parameters
Set uNamed = WScript.Arguments.Unnamed

'Ensure that we have at least one
If uNamed.Count = 0 Then
	WScript.Arguments.ShowUSage
	WScript.Quit 1
End If

'Ensure that they are four-digit numbers
For Each strYear in uNamed
	If Not IsNumeric(strYear) Then
		WScript.Arguments.ShowUsage
		WScript.Quit 1
	End If
	If Len(strYear) <> 4 Then
		WScript.Arguments.ShowUsage
		WScript.Quit 1
	End If
Next

For Each strYear in uNamed
	SO.WriteLine "Looking to combine lists for the year " & strYear
	'Look for matching lists
	Set colLists = SCCM.Get("SMS_AuthorizationList").Instances_
	Set Updates = CreateObject("Scripting.Dictionary")
	UpdateCount = 0
	For Each ListItem in colLists
		If Left(UCase(ListItem.LocalizedDisplayName),22) = "SOFTWARE UPDATES " & strYear & "-" Then
			Set List = SCCM.Get(Split(ListItem.Path_,":")(1))	'Need to get the object due to lazy properties
			SO.WriteLine "  " & List.LOcalizedDisplayName
			'Get the updates that are in this list
			Set collUpdateIDs = SCCM.ExecQuery("Select SMS_SoftwareUpdate.* from SMS_CIRelation join SMS_SoftwareUpdate on SMS_CIRelation.ToCIID=SMS_SoftwareUpdate.CI_ID where SMS_CIRelation.FromCIID=" & List.CI_ID)
			If collUpdateIDs.Count > 0 Then
				For Each Update in collUpdateIDs
					Updates.Add CStr(Update.CI_ID), Update
					UpdateCOunt = UpdateCount + 1
				Next
			End If
		End If
	Next

	'We now have all of our updates into the Updates array
	SO.WriteLine "    " & UpdateCount & " update(s) to be combined into a single list"

	Set Info = SCCM.Get("SMS_CI_LocalizedProperties").SpawnInstance_
	Info.Description = "Auto-generated Update List"
	Info.DisplayName = "Software Updates " & strYear & " Annual Summary"
	Info.InformativeURL = ""
	Info.LocaleID="1033"
	Set List = SCCM.Get("SMS_AuthorizationList").SpawnInstance_
	List.Updates = Updates.Keys
	List.LocalizedInformation = Array(Info)
	List.Put_
Next

</script>
</job>

This script requires that the content for the update list specified be downloaded into a deployment package and that any EULAs have been accepted. Otherwise, it will produce errors.

The script creates output, so it should be run under CSCRIPT on the site server itself.

The script was written for a particular process, which you’ll want to modify for your environment. At the place where I work, we deploy updates initially to a “Dogfood” group that performs initial testing to ensure that the updates don’t cause bluescreens or other major havoc. The next phase sees the deployment to the “Tech” team (the whole IT department), followed by a deployment to the production workstations. We also have separate collections for production servers and for computers that represent the operating system image source. Because of that, there are several different groups where you’ll want to update the collection ID to match your environment.

Also, don’t forget to update the sitecode to the one for your environment.

The way the script works, you can combine several groups on the command line at once (for example, /D /S /I to deploy to Dogfood, Servers, and Image computers simultaneously). The script handles all of the deployment settings, so you don’t actually need deployment templates for this to work. I still recommend them for manual deployments or other one-offs so that you can remain consistent.

Save the following as DeployUpdates.wsf:

<job>
<runtime>
<description>
This script will create a deployment for the named Update List and
assign it to the specified target(s).

This script does NOT use the templates found in SCCM.  Any changes
needed to the template must be coded in the script.
</description>
<named name="L" type=string helpstring="Name of the update list" required=true />
<named name="D" type=simple helpstring="Deploy to DOGFOOD" />
<named name="I" type=simple helpstring="Deploy to IMAGE" />
<named name="S" type=simple helpstring="Deploy to SVR" />
<named name="T" type=simple helpstring="Deploy to TECH" />
<named name="W" type=simple helpstring="Deploy to WKS" />
</runtime>
<script language="VBScript">

Const DogfoodCollectionID = "***ID***"
Const DogfoodDeadline = -1
Const DogfoodNotify = False

Const ImageCollectionID = "***ID***"
Const ImageDeadline = -1
Const ImageNotify = True

Const SvrCollectionID = "***ID***"
Const SvrDeadline = 1
Const SvrNotify = True

Const TechCollectionID = "***ID***"
Const TechDeadline = -1
Const TechNotify = False

Const WksCollectionID = "***ID***"
Const WksDeadline = -1
Const WksNotify = False

Const SiteCode = "***"

'Get SCCM WMI Connection
Set SCCM = GetObject("winmgmts://./root/sms/site_" & SiteCode)
Set WMIDate = CreateObject("WbemScripting.SWbemDateTime")

'Check named arguments
Set aNamed = WScript.Arguments.Named
If Not aNamed.Exists("L") Then
	'Missing list
	WScript.Arguments.ShowUsage
	WScript.Quit 1
End If
If Not (aNamed.Exists("D") or aNamed.Exists("I") or aNamed.Exists("S") or aNamed.Exists("T") or aNamed.Exists("W")) Then
	'Missing target
	WScript.Arguments.ShowUsage
	WScript.Quit 1
End If

'See if the list exists
Set RS = SCCM.ExecQuery("select * from SMS_AuthorizationList where LocalizedDisplayName='" & aNamed("L") & "'")
If RS.Count = 0 Then
	WScript.Echo "The Update List " & aNamed("L") & " cannot be found.  Please check spelling."
	WScript.Quit 1
End If

'Get the corrected name so that letter case matches what is visible to the user
For Each AL in RS
	Set lbAL = SCCM.Get("SMS_AuthorizationList.CI_ID=" & AL.CI_ID)
	UpdateListName = lbAL.LocalizedDisplayName
	UpdateArray = lbAL.Updates
Next
WScript.Echo "Creating deployments for " & UpdateListName
WScript.Echo "This deployment will be for " & UBound(UpdateArray)+1 & " update(s)"

'Create the deployments requested
If aNamed.Exists("D") Then AddDeployment " to DOGFOOD", DogfoodCollectionID, DogfoodDeadline, DogfoodNotify
If aNamed.Exists("I") Then AddDeployment " to IMAGE", ImageCollectionID, ImageDeadline, ImageNotify
If aNamed.Exists("S") Then AddDeployment " to SVR", SvrCollectionID, SvrDeadline, SvrNotify
If aNamed.Exists("T") Then AddDeployment " to TECH", TechCollectionID, TechDeadline, TechNotify
If aNamed.Exists("W") Then AddDeployment " to WKS", WksCollectionID, WksDeadline, WksNotify

Sub AddDeployment(NameSuffix, TargetCollectionID, SetDeadline, NotifyUser)
	WScript.Echo "Adding deployment" & NameSuffix
	Set UA = SCCM.Get("SMS_UpdatesAssignment").SpawnInstance_

	UA.ApplyToSubTargets = False
	UA.AssignedCIs = UpdateArray
	UA.AssignmentAction = 2		'This will apply the updates (not just detect them)
	UA.AssignmentDescription = ""
	UA.AssignmentName = UpdateListName & NameSuffix
	UA.DesiredConfigType = 1	'Updates are REQUIRED
	UA.DPLocality = 80			'Download from local and remote distribution points
	UA.LocaleID = 1033			'English
	UA.LogComplianceToWinEvent = True
	UA.NotifyUser = NotifyUser
	UA.OverrideServiceWindows = False
	UA.RaiseMomAlertsOnFailure = False
	UA.ReadOnly = False
	UA.RebootOutsideOfServiceWindows = False
	UA.SendDetailedNonComplianceStatus = True
	If SetDeadline >= 0 Then
		WMIDate.SetVarDate DateAdd("h",SetDeadline,Now())
		WMIDate.UTCSpecified = False
		UA.EnforcementDeadline = WMIDate.Value
	End If
	WMIDate.SetVarDate(Now())
	WMIDate.UTCSpecified = False
	UA.StartTime = WMIDate.Value
	UA.SuppressReboot = 0
	UA.TargetCollectionID = TargetCollectionID
	UA.UseGMTTimes = False

	UA.Put_
End Sub

</script>
</job>

In this first article, I want to share a script that I use to actually create the update list. This script will search for updates that have not yet been deployed and that are actually required by at least one client system (so you need to usually wait a day or so for inventory of any new updates to be gathered).

The script will default to creating an update list called Software Updates YYYY-MM for the current month. If one already exists, it appends a lowercase letter to the end to provide unique update lists.

Once the update list is created, you can go into the ConfigMgr console to actually review the list (to ensure that it is or is not deploying the latest Internet Explorer, for example), to accept any EULAs, and to actually download the updates into a deployment package.

This script should be run from the ConfigMgr site server itself. Be sure to replace the *** in the “set SCCM” line to your site code. This script produces output and should be run under CSCRIPT.

For command-line options, run the script with the “/?” switch.

Save the following as UpdateList.wsf:

<job>
<runtime>
<description>
This script will create an update list that contains updates according to the
criteria specified on the command line.
</description>
<named name=Range					helpstring="Range of months back from today to search for updates                           (default 2)" type=string required=false />
<named name=IncludeDeployed 		helpstring="Include updates that have already been deployed" type=simple required=false />
<named name=IncludeUnrequired		helpstring="Include updates that are not required" type=simple required=false />
<named name=Categories 				helpstring="Specifies categories to include separated by commas                             (default SU,CU,UR,DU)" type=string required=false />
<named name=ListName				helpstring="Name of the Update List to create                                               (default Software Updates YYYY-MM)" type=string required=false />
<named name=IncludeProducts			helpstring="Display names of products to include updates for,								regardless of category (default Silverlight)" type=string required=false />
</runtime>
<script language=vbscript>

'Connect to SCCM WMI provider
set SCCM = GetObject("winmgmts://./root/sms/site_***") 'Replace *** with your sitecode!

Set WMIDate = CreateObject("WbemScripting.SWbemDateTime")

'Note any articles that should _never_ be automatically included
ArticlesToNeverInclude=Array("974571")

'Note any products that should _never_ be automatically included
ProductsToNeverInclude=Array("ProductFamily:352f9494-d516-4b40-a21a-cd2416098982", _
		"Product:83a83e29-7d55-44a0-afed-aea164bc35e6", _
		"Product:3cf32f7c-d8ee-43f8-a0da-8b88a6f8af1a", _
		"Product:26bb6be1-37d1-4ca6-baee-ec00b2f7d0f1", _
		"Product:9b135dd5-fc75-4609-a6ae-fb5d22333ef0")	'All versions of Exchange server

'Set variables based on parameters

Range = 2
If WScript.Arguments.Named.Exists("Range") Then
	If IsNumeric(WScript.Arguments.Named("Range")) Then Range = WScript.Arguments.Named("Range")
End If
RangeStart = DateAdd("m",0-Range,Now())

IncludeDeployed = False
If WScript.Arguments.Named.Exists("IncludeDeployed") Then IncludeDeployed = True

IncludeUnrequired = False
If WScript.Arguments.Named.Exists("IncludeUnrequired") Then IncludeUnrequired = True

Categories = "SU,CU,UR,DU"
If WScript.Arguments.Named.Exists("Categories") Then Categories = UCase(WScript.Arguments.Named("Categories"))

IncludeProducts = "Silverlight,PowerShell"
If WScript.Arguments.Named.Exists("IncludeProducts") Then IncludeProducts = WScript.Arguments.Named("IncludeProducts")

ListName = "Software Updates " & Year(Now()) & "-"
If Month(Now())<10 Then ListName = ListName & "0"
ListName = ListName & Month(Now())
If WScript.Arguments.Named.Exists("ListName") Then ListName = WScript.Arguments.Named("ListName")

'Create category filter
If InStr(Categories,",") Then arrCat = Split(Categories,",") Else arrCat = Array(Categories)
WQL = "Select * from SMS_UpdateCategoryInstance where CategoryTypeName='UpdateClassification'"
Set SCCMCats = SCCM.ExecQuery(WQL)
For Each SCCMCat in SCCMCats
	If Instr(SCCMCat.LocalizedCategoryInstanceName," ") Then Words = Split(SCCMCat.LocalizedCategoryInstanceName," ") Else Words=Array(SCCMCat.LocalizedCategoryInstanceName)
	Initials = ""
	For I = LBound(Words) to UBound(Words)
		Initials = Initials & UCase(Left(Words(I),1))
	Next
	For I = LBound(arrCat) to UBound(arrCat)
		If arrCat(I) = Initials Then arrCat(I) = SCCMCat.CategoryInstance_UniqueID
	Next
Next
CategoryFilter = " and ("
For I = LBound(arrCat) to UBound(arrCat)
	CategoryFilter = CategoryFilter & "CategoryInstance_UniqueIDs='" & arrCat(I) & "' or "
Next

'Include product filter
If Instr(IncludeProducts,",") Then arrProducts = Split(IncludeProducts,",") Else arrProducts = Array(IncludeProducts)
WQL = "Select * from SMS_UpdateCategoryInstance where CategoryTypeName='Product'"
Set SCCMProds = SCCM.ExecQuery(WQL)
For Each SCCMProd in SCCMProds
	For I = LBound(arrProducts) to UBound(arrProducts)
		If UCase(SCCMProd.LocalizedCategoryInstanceName) = UCase(arrProducts(I)) Then arrProducts(I) = SCCMProd.CategoryInstance_UniqueID
	Next
Next
For I = LBound(arrProducts) to UBound(arrProducts)
	CategoryFilter = CategoryFilter & "CategoryInstance_UniqueIDs='" & arrProducts(I) & "' or "
Next

CategoryFilter = Left(CategoryFilter,Len(CategoryFilter)-4) & ")"

'Exclude Article Filter
ArticleFilter = " and not ("
For I = LBound(ArticlesToNeverInclude) to UBound(ArticlesToNeverInclude)
	ArticleFilter = ArticleFilter & "ArticleID='" & ArticlesToNeverInclude(I) & "' or "
Next
ArticleFilter = Left(ArticleFilter,Len(ArticleFilter)-4) & ")"

'Exclude Product Filter
ProductFilter = " and not ("
For I = LBound(ProductsToNeverInclude) to UBound(ProductsToNeverInclude)
	ProductFilter = ProductFilter & "CategoryInstance_UniqueIDs='" & ProductsToNeverInclude(I) & "' or "
Next
ProductFilter = Left(ProductFilter,Len(ProductFilter)-4) & ")"

'Locate updates that match our criteria
WScript.Echo "Querying for updates..."
WQL = "Select * from SMS_SoftwareUpdate where IsExpired=0 and DateRevised >= '" & RangeStart & "' and LocalizedDisplayName not like '%for Itanium-based Systems%'"
WQL = WQL & " and LocalizedDisplayName not like '%IA64-based%' and LocalizedDisplayName not like '%Windows Embedded%'"
If Not IncludeDeployed Then WQL = WQL & " and IsDeployed=0"
If Not IncludeUnrequired Then WQL = WQL & " and NumMissing>0"
WQL = WQL & CategoryFilter & ArticleFilter & ProductFilter
'WScript.Echo WQL
Set UpdateCollection=SCCM.ExecQuery(WQL)
WScript.Echo "...Found " & UpdateCollection.Count & " update(s) that match criteria"

Dim UpdateCI_IDs()
Redim UpdateCI_IDs(-1)

For Each Update in UpdateCollection
	'Apply some filters to the updates
	WScript.Echo Update.ArticleID & vbTab & Update.DateRevised & vbTab & Update.LocalizedDisplayName
	Redim Preserve UpdateCI_IDs(UBound(UpdateCI_IDs)+1)
	UpdateCI_IDs(UBound(UpdateCI_IDs)) = Update.CI_ID
Next

WScript.Echo
WScript.Echo  "Press ENTER to create the list"
X = WScript.StdIn.ReadLine

'Ensure that the list name is unique
ListNameToUse=ListName
I = 96
WQL = "Select * from SMS_AuthorizationList where LocalizedDisplayName like '" & ListName & "%'"
Set ExistingLists = SCCM.ExecQuery(WQL)
For Each ListItem in ExistingLists
	If Not IsNumeric(Right(ListItem.LocalizedDisplayName,1)) Then
		C = Asc(Right(ListItem.LocalizedDisplayName,1))
		If C > I Then I = C
	End If
Next
If ExistingLists.Count > 0 Then ListNameToUse = ListName & Chr(I+1)
WScript.Echo "Creating Update List " & ListNameToUse

Set Info = SCCM.Get("SMS_CI_LocalizedProperties").SpawnInstance_
Info.Description="Auto-generated Update List"
Info.DisplayName=ListNameToUse
Info.InformativeURL=""
Info.LocaleID="1033"
Set List = SCCM.Get("SMS_AuthorizationList").SpawnInstance_
List.Updates = UpdateCI_IDs
List.LocalizedInformation = Array(Info)
List.Put_
</script>
</job>